TU-Dresden » Startseite Forum » Forum

TU-Dresden Forum

Aktuelle Zeit: Donnerstag 9. Dezember 2021, 02:37

Alle Zeiten sind UTC + 1 Stunde




Ein neues Thema erstellen Auf das Thema antworten  [ 43 Beiträge ]  Gehe zu Seite Vorherige  1, 2, 3, 4, 5  Nächste
Autor Nachricht
 Betreff des Beitrags: Re: Schrifteninstallation unter windows 7 mit MiKTeX 2.8
BeitragVerfasst: Donnerstag 23. September 2010, 17:18 
Offline

Registriert: Donnerstag 23. September 2010, 17:15
Beiträge: 1
Danke für das Skript. Damit hat es fast auf Anhieb geklappt (MiKTeX 2.8 auf Windows 7 (32 Bit)).

In der dritt- bzw. viertletzten Zeile des Batch-Skriptes fehlt jedoch Folgendes:

echo map dinbold.map >> "%CommonConfig%\miktex\config\updmap.cfg"


Nach oben
 Profil  
Mit Zitat antworten  
 Betreff des Beitrags: Re: Schrifteninstallation unter windows 7 mit MiKTeX 2.8
BeitragVerfasst: Montag 27. September 2010, 08:19 
Offline

Registriert: Montag 19. Oktober 2009, 12:49
Beiträge: 32
dstein hat geschrieben:
echo map dinbold.map >> "%CommonConfig%\miktex\config\updmap.cfg"

der echo-befehl gibt doch nur eine zeichenkette auf der konsole aus. er führt selbst gar nichts aus. das heißt, dass deine ergänzung funktional keine verbesserung bringt, sondern nur etwas auf der konsole ausgibt.


Nach oben
 Profil  
Mit Zitat antworten  
 Betreff des Beitrags: Re: Schrifteninstallation unter windows 7 mit MiKTeX 2.8
BeitragVerfasst: Dienstag 28. September 2010, 09:26 
Offline

Registriert: Mittwoch 25. November 2009, 10:04
Beiträge: 62
SidKennedy hat geschrieben:
dstein hat geschrieben:
echo map dinbold.map >> "%CommonConfig%\miktex\config\updmap.cfg"

der echo-befehl gibt doch nur eine zeichenkette auf der konsole aus. er führt selbst gar nichts aus. das heißt, dass deine ergänzung funktional keine verbesserung bringt, sondern nur etwas auf der konsole ausgibt.


Nein. Die Ausgabe des echo-Befehls wird durch die Umleitung ">>" ans Ende der updmap.cfg geschrieben.

Martin


Nach oben
 Profil  
Mit Zitat antworten  
 Betreff des Beitrags: Re: Schrifteninstallation unter windows 7 mit MiKTeX 2.8
BeitragVerfasst: Samstag 11. Dezember 2010, 13:55 
Offline

Registriert: Samstag 11. Dezember 2010, 13:47
Beiträge: 1
Das Skript hat bei mir nicht (ganz?) funktioniert, nach der Installation fehlte pdfTeX eine Schriftart (irgendein Source file fehlte).

Nach ein wenig suchen im Netz, bin ich auf den Hinweis gestoßen, die .map-Dateien in den Ordner map localtexmf/tex/pdftex/config/ zu kopieren. Danach ging alles reibungslos (sogar ohne FNDB-Update).

Meins: MiKTeX 2.9, Win XP


Nach oben
 Profil  
Mit Zitat antworten  
 Betreff des Beitrags: Re: Schrifteninstallation unter windows 7 mit MiKTeX 2.8
BeitragVerfasst: Montag 4. April 2011, 09:40 
Offline

Registriert: Dienstag 14. September 2010, 09:26
Beiträge: 25
Hallo,

nach meinem letzten Post ist ja einige Zeit ins Land gegangen und ich habe ein wenig an dem batch-File gearbeitet.
Es gibt folgende Neuerungen in der Datei sowie in dem Posting:

  • Erstellung eines temporären Arbeitsverzeichnisses (z.B. zum Entpacken)
  • Installation des Pakets fontinst vom Dante Repository (http)
  • Anpassung der Pfade zu den ausführbaren TeX-Dateien (sinnvoll, wenn mehrere MiKTeX Installationen vorhanden sind oder die Vorlage bei lokal installiertem MiKTeX auf die portable-Version installiert werden soll)
  • Anpassung der Hyperlinks
  • Abbildung der Verzeichnisstruktur eingefügt
Update 04.06.2011
  • Anpassung an die neuen Vorlagen mit Stand 04.05.2011 (Anpassung der Links zur TU-Website)
  • batch muss bei neueren Windows-Versionen mit Admin-Rechten ausgeführt werden, da sonst kein Zugriff auf das Program Files-Verzeichnis erlaubt wird


Getestet unter:

  • Windows XP Prof. x86 - MiKTeX 2.8/2.9/portable
  • Windows 7 Prof. x64 - MiKTeX 2.8/2.9/portable


Vorgehensweise:

Folgende Dateien herunterladen und in das selbe Verzeichnis wie die Batch-Datei kopieren (Verzeichnis kann beliebig gewählt werden und muss nicht im MiKTeX Installationsverzeichnis erstellt werden):

  • http://tu-dresden.de/service/cd/4_latex/dat/update_110504/tud_vorlagen_komplett_20110504.zip
  • http://sourceforge.net/projects/sevenzip/files/7-Zip/9.20/7za920.zip/download

Die 7za920.zip manuell in das gleiche Verzeichnis entpacken. Es handelt sich hierbei um die Command Line Version des quelloffenen zip-Programms 7-zip.


zip-Dateien der Schriften hinzufügen aber nicht entpacken:

  • Univers_ps.zip
  • DIN_Bd_PS.zip

Der Inhalt des Verzeichnisses sollte dem im Anhang dieses Postings dargestellten entsprechen.

Abschließend die folgende bat-Datei mit Administratoren-Rechten starten (sollten keine Admin-Rechte vorhanden sein, werden Modifikationen an der bat-Datei notwendig..
Da das Forum derzeit keine txt/bat Dateianhänge zulässt, muss der Code kopiert, in einem Texteditor eingefügt und als .bat-Datei abgespeichert werden.
Code:
@echo off
cd /d %~dp0
cls
echo.
echo   Installation der TU Vorlage Schriftarten unter MiKTeX 2.7/2.8/2.9/portable
echo  ==============================================================================
echo.
echo.
echo HINWEIS: Alle hier angegebenen Verzeichnisse finden Sie im Settings-
echo          Programm von MiKTeX unter dem Reiter "Roots".
echo.
echo  ==============================================================================
echo.
echo Bitte geben Sie den Pfad zum MiKTeX-Installationsverzeichnis ein!
echo Zum Beispiel:
echo          "C:\Program Files (x86)\MiKTeX 2.x"
echo          "C:\Program Files\MiKTeX 2.x"
echo          "C:\Programme\MiKTeX 2.x"
echo.
echo.
:proof_Install
set /p Install=MiKTeX-Verzeichnis (ohne Anfuerungszeichen):
echo.
if not exist "%Install%\miktex\bin\tex.exe" (
echo FEHLER: Das angebene Verzeichnis scheint nicht das MiKTeX-Verzeichnis
echo         zu sein ^(tex.exe nicht gefunden^)!
echo         Bitte geben Sie den Pfad zu MiKTeX ein!
echo.
echo.
goto proof_Install
)
echo.
if not "%UserConfig%" == "" goto start_install
echo.
echo  ==============================================================================
echo.
echo Bitte geben Sie den Pfad zum CommonConfig-Verzeichnis ein!
echo HINWEIS: Fuer die portable Version entspricht das CommonConfig dem Installationsverzeichnis.
echo Zum Beispiel:
echo          "C:\Dokumente und Einstellungen\All Users\Anwendungsdaten\MiKTeX\2.x"
echo          "C:\Documents and Settings\All Users\Application Data\MiKTeX\2.x"
echo          "C:\ProgramData\MiKTeX\2.x"
echo.
echo.
:proof_CommonConfig
set /p CommonConfig=CommonConfig-Verzeichnis (ohne Anfuehrungszeichen):
if not exist "%CommonConfig%\fontconfig\config\fonts.conf" (
echo FEHLER: Das angebene Verzeichnis scheint nicht das CommonConfig-Verzeichnis
echo         zu sein ^(fonts.conf nicht gefunden^)!
echo         Bitte geben Sie den Pfad zu MiKTeX ein!
echo.
echo.
goto proof_CommonConfig
)
rmdir /s /q temp > nul

REM Entpacken der Vorlagendatei; kopieren der Vorlagen- und Dokumentationsdateien ins LaTeX-Verzeichnis; Entpacken der Schriften
7za e tud_vorlagen_komplett_20110504.zip -o"temp" -y
7za e temp\vorlagen_20110504.zip -o"%install%\tex\latex\tud\" -y
7za e Univers_ps.zip -o"temp" -y
7za e DIN_Bd_PS.zip -o"temp" -y
set PATH=%PATH%;"%install%\miktex\bin"
7za e temp\anhaenge_20110504.zip -o"%install%\doc\latex\tud\" *.tex -y
7za e temp\anhaenge_20110504.zip -o"%install%\tex\latex\tud\" *.pdf *.eps *.sty -y
move /y temp\Handbuch.pdf "%install%\doc\latex\tud\"
pause
rmdir /s /q temp\converted > nul
mkdir temp\converted
cd /d %~dp0temp
rem uvceb aunb8a
copy uvceb___.pfb converted\aunb8a.pfb > nul
copy uvceb___.afm converted\aunb8a.afm > nul
rem uvcel aunl8a
copy uvcel___.pfb converted\aunl8a.pfb > nul
copy uvcel___.afm converted\aunl8a.afm > nul
rem uvceo aunro8a
copy uvceo___.pfb converted\aunro8a.pfb > nul
copy uvceo___.afm converted\aunro8a.afm > nul
rem uvxbo aunbo8a
copy uvxbo___.pfb converted\aunbo8a.pfb > nul
copy uvxbo___.afm converted\aunbo8a.afm > nul
rem uvxlo aunlo8a
copy uvxlo___.pfb converted\aunlo8a.pfb > nul
copy uvxlo___.afm converted\aunlo8a.afm > nul
rem uvce  aunr8a
copy uvce____.pfb converted\aunr8a.pfb > nul
copy uvce____.afm converted\aunr8a.afm > nul
rem uvczo aubro8a
copy uvczo___.pfb converted\aubro8a.pfb > nul
copy uvczo___.afm converted\aubro8a.afm > nul
rem uvcz  aubr8a
copy uvcz____.pfb converted\aubr8a.pfb > nul
copy uvcz____.afm converted\aubr8a.afm > nul

rem din-bold
copy DINBd___.pfb converted\dinb8a.pfb > nul
copy DINBd___.afm converted\dinb8a.afm > nul

cd converted

echo \input fontinst.sty > ltx.tex
echo \latinfamily{aun}{} >> ltx.tex
echo \latinfamily{din}{} >> ltx.tex
echo \bye >> ltx.tex
"%install%\miktex\bin\mpm" --set-repository=http://ftp.dante.de/tex-archive/systems/win32/miktex/tm/packages/ --install=fontinst --verbose
"%install%\miktex\bin\tex" ltx.tex

echo \input fontinst.sty > ltx.tex
echo \latinfamily{aub}{} >> ltx.tex
echo \latinfamily{din}{} >> ltx.tex
echo \bye >> ltx.tex
"%install%\miktex\bin\tex" ltx.tex

dir /b *.pl > files.txt
for /f "delims=. " %%i in (files.txt) do pltotf %%i.pl %%i.tfm

dir /b *.vpl > files.txt
for /f "delims=. " %%i in (files.txt) do vptovf %%i.vpl %%i.vf %%i.tfm

echo aunb8r UniversCE-Bold "Univers" ^<8r.enc ^<aunb8a.pfb > univers.map
echo aunl8r UniversCE-Light "Univers" ^<8r.enc ^<aunl8a.pfb >> univers.map
echo aunro8r UniversCE-Oblique "Univers" ^<8r.enc ^<aunro8a.pfb >> univers.map
echo aunbo8r UniversCE-BoldOblique "Univers" ^<8r.enc ^<aunbo8a.pfb >> univers.map
echo aunlo8r UniversCE-LightOblique "Univers" ^<8r.enc ^<aunlo8a.pfb >> univers.map
echo aunr8r UniversCE-Medium "Univers" ^<8r.enc ^<aunr8a.pfb >> univers.map
echo aubro8r Univers-BlackOblique "Univers" ^<8r.enc ^<aubro8a.pfb >> univers.map
echo aubr8r Univers-Black "Univers" ^<8r.enc ^<aubr8a.pfb" >> univers.map
echo dinb8r DINBold "DIN-Bold" ^<8r.enc ^<dinb8a.pfb > dinbold.map

mkdir "%install%\tex\latex\univers"
mkdir "%install%\fonts\tfm\public\univers"
mkdir "%install%\fonts\afm\public\univers"
mkdir "%install%\fonts\vf\public\univers"
mkdir "%install%\fonts\type1\public\univers"
mkdir "%CommonConfig%\miktex\config"

copy /y *.fd  "%install%\tex\latex\univers\"
copy /y *.tfm "%install%\fonts\tfm\public\univers\"
copy /y *.afm "%install%\fonts\afm\public\univers\"
copy /y *.vf  "%install%\fonts\vf\public\univers\"
copy /y *.pfb "%install%\fonts\type1\public\univers\"
copy /y *.map "%CommonConfig%\dvips\config"

findstr /v /i /c:"map univers.map" /c:"map dinbold.map" "%CommonConfig%\miktex\config\updmap.cfg" > "%CommonConfig%\miktex\config\updmap.temp"
echo.>>"%CommonConfig%\miktex\config\updmap.temp"
del /f "%CommonConfig%\miktex\config\updmap.cfg"
ren "%CommonConfig%\miktex\config\updmap.temp" updmap.cfg
echo Map univers.map>>"%CommonConfig%\miktex\config\updmap.cfg"
echo Map dinbold.map>>"%CommonConfig%\miktex\config\updmap.cfg"

"%install%\miktex\bin\initexmf" --mkmaps --verbose
"%install%\miktex\bin\initexmf" --admin --update-fndb --verbose
echo.
echo.
echo Installation abgeschlossen!
echo Clean up temp dir
cd /d %~dp0
rmdir /s/q temp
pause


Beste Grüße
Thomas


Dateianhänge:
Dateikommentar: Verzeichnisstruktur vor Installationsbeginn
struktur.jpg
struktur.jpg [ 41.1 KiB | 4763-mal betrachtet ]


Zuletzt geändert von gefluegelschere am Montag 6. Juni 2011, 14:00, insgesamt 2-mal geändert.
Nach oben
 Profil  
Mit Zitat antworten  
 Betreff des Beitrags: Re: Schrifteninstallation unter windows 7 mit MiKTeX 2.8
BeitragVerfasst: Freitag 13. Mai 2011, 16:08 
Offline

Registriert: Montag 29. März 2010, 20:10
Beiträge: 11
Möchte mich für deinen Post bedanken.
Hab hier schon einige Nerven verloren.
Nachdem ich den letzten Post gelesen habe, lief's in 5min.

Läuft also auch unter:

Windows 7 32bit - MiKTeX 2.9

Edit: Habe es nun auch auf meinem großen Rechner probiert (neuerdings Windows 7 64bit - MiKTeX 2.9).
Wie immer bei Latex viele Nerven verloren. Lösung war ein Refresh der FNDB nach dem Ausführen der oben genannten Schritte.


Nach oben
 Profil  
Mit Zitat antworten  
 Betreff des Beitrags: Re: Schrifteninstallation unter windows 7 mit MiKTeX 2.8
BeitragVerfasst: Montag 16. Mai 2011, 10:41 
Offline

Registriert: Dienstag 14. September 2010, 09:26
Beiträge: 25
Eigentlich wird in der Batch-Datei ein FNDB-Update durchgeführt. Kommt am Ende vielleicht auch darauf an, ob das Ganze möglicherweise als Admin ausgeführt wird, dann müsste noch die Option --admin ergänzt werden.


Nach oben
 Profil  
Mit Zitat antworten  
 Betreff des Beitrags: Re: Schrifteninstallation unter windows 7 mit MiKTeX 2.8
BeitragVerfasst: Dienstag 5. Juli 2011, 10:26 
Offline

Registriert: Dienstag 14. September 2010, 09:26
Beiträge: 25
Nachdem ich an siunitx verzweifelt bin und schon fast LaTeX abgeschworen hatte, habe ich mal die 64bit Version von MiKTeX 2.9 x64 installiert.
Diese ist zwar noch in einem experimentellen Stadium, hat sich aber bisher bewährt und keine Schwächen im Vergleich zur x86-Version gezeigt. Die Schriftinstallation bleibt grundsätzlich gleich und funktioniert ohne Probleme (getestet). Es muss nur jedes \bin mit \bin\x64 ersetzt werden. Das Notepad wird euch mit Strg+H behilflich sein.


Nach oben
 Profil  
Mit Zitat antworten  
 Betreff des Beitrags: Re: Schrifteninstallation unter windows 7 mit MiKTeX 2.8
BeitragVerfasst: Freitag 9. September 2011, 15:03 
Offline

Registriert: Freitag 9. September 2011, 14:57
Beiträge: 541
Hallo zusammen,
erstmal besten Dank an Thomas für das Script. Wollte nur kurz melden, dass sich da ein kleiner Fehler eingeschlichen hat. In der Zeile:
Code:
echo aubr8r Univers-Black "Univers" ^<8r.enc ^<aubr8a.pfb" >> univers.map

sind die Anführungsstriche hinter aubr8a.pfb zu viel. Es sollte heißen:
Code:
echo aubr8r Univers-Black "Univers" ^<8r.enc ^<aubr8a.pfb >> univers.map

LG
Falk

_________________
TUD-Script-Klassen für das Corporate Design der TU Dresden

Anwenderhandbuch: CTAN-Mirror oder texdoc tudscr
Anwenderleitfaden: CTAN-Mirror oder texdoc treatise
Schriftinstallation: Skripte zum Download

LyX-Layoutdateien und Befehlsvervollständigung für TeXstudio
Übersicht zu allen veröffentlichten Versionen


Nach oben
 Profil  
Mit Zitat antworten  
 Betreff des Beitrags: Re: Schrifteninstallation unter windows 7 mit MiKTeX 2.8
BeitragVerfasst: Samstag 18. Februar 2012, 22:04 
Offline

Registriert: Samstag 18. Februar 2012, 22:01
Beiträge: 1
Hallo leider kann er bei mir die ltx.tex einfach nicht finden und bricht damit das Script immer wieder ab. Es sei gesagt, dass ich es unter Windows XP versuche. Admin bin ich. Leider weiss ich einfach nicht weiter.

Danke für die Hilfe...


Nach oben
 Profil  
Mit Zitat antworten  
Beiträge der letzten Zeit anzeigen:  Sortiere nach  
Ein neues Thema erstellen Auf das Thema antworten  [ 43 Beiträge ]  Gehe zu Seite Vorherige  1, 2, 3, 4, 5  Nächste

Alle Zeiten sind UTC + 1 Stunde


Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 1 Gast


Du darfst keine neuen Themen in diesem Forum erstellen.
Du darfst keine Antworten zu Themen in diesem Forum erstellen.
Du darfst deine Beiträge in diesem Forum nicht ändern.
Du darfst deine Beiträge in diesem Forum nicht löschen.
Du darfst keine Dateianhänge in diesem Forum erstellen.

Suche nach:
cron